Mailing list system that supports ms access?

[jnroche]

Helllo guys!

can someone point me to a good mailing list system that has a free trial and that supports ms access?


thanks in advance!

[wisemx]

...I've got a few in my old Classic ASP archives.
Will look through those files later but...Do you promise to use this only for good things? ;-)
(No spam, nothing harmful)
All the best,
Mark

[jnroche]

but im using aspx/.net? is that possible still? yeah this is not spamming, visitors have to be opted-in before they receive emails....

thanks in advance!

[wisemx]

OK I'll look around.
Keep in mind something like this should go down the tracks with SQL Sever, not Access. ;-)

[jnroche]

yeah, sql is better but my client does not have ms sql on their server package. only ms access via odbc. if that makes sense. i have to request them to have it upgraded to include ms sql but for now they just need it.

Thanks a lot for helping. I'm still learning asp.net and server configuration and stuffs.

[jnroche]

hi!

i was looking around as well and found digsolNOSv100 however, when i try to send an email to one email address it says message sent to [email address] but i dont actually receive it... the code for the mail.asp is:

<!--Copyright 2002, Dan Hounshell, Digger Solutions. All rights reserved.
This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 2.5 License.
To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/2.5/
or send a letter to Creative Commons, 543 Howard Street, 5th Floor, San Francisco, California, 94105, USA. -->


<%Sub SendEmail(eToName, eToEmail, eFromName, eFromEmail, eSubject, eBody, eCCName, eCCEmail, _
eBCCName, eBCCEmail, eAttachedFile, eBoolHTML)

if gsMailComponent = "CDO" then

Set Mailer = Server.CreateObject("CDO.Message")
Mailer.To = eToEmail
Mailer.From = eFromEmail
Mailer.Subject = eSubject
Mailer.Body = eBody
if eAttachedFile <> "" then
Mailer.AttachFile = eAttachedFile
end if
if eCCEmail <> "" then
Mailer.Cc = eCCEmail
end if
if eBCCEmail <> "" then
Mailer.Bcc = eBCCEmail
end if
if eBoolHTML then
Mailer.BodyFormat = 0
Mailer.MailFormat = 0
end if
Mailer.Send
Set Mailer = Nothing

elseif gsMailComponent = "ASPXP" then

Set mail = Server.CreateObject("ASPXP.Mail")
mail.Host = gsMailHost
mail.Port = 25
mail.Subject = eSubject
mail.FromName = eFromName
mail.FromAddress = eFromEmail
'mail.Importance = 2
mail.ToList.Add eToEmail, EToName
if eBoolHTML then
mail.HTMLBody = eBody
else
mail.PlainBody = eBody
end if
if eCCEmail <> "" then
mail.CCList.Add eCCEmail, eCCName
end if
if eBCCEmail <> "" then
mail.BCCList.Add eBCCEmail, eBCCName
end if
if eAttachedFile <> "" then
mail.Attachments.Add eAttachedFile
end if

on error resume next
mail.Send

set mail = nothing

elseif gsMailComponent = "PersitsASPMail" then
'this is just the framework, it needs to be setup for attachment, cc, bcc, etc

set mail = server.CreateObject("Persits.MailSender")
mail.Host = gsMailHost
mail.From = eFromEmail
mail.FromName = eFromName
mail.AddAddress eToEmail
mail.AddReplyTo eFromEmail
mail.Subject = eSubject
mail.Body = eBody

on error resume next
mail.Send

elseif gsMailComponent = "Jmail" then
'this is just the framework, it needs to be setup for attachment, cc, bcc, etc

set mail = server.CreateOBject( "JMail.Message" )
mail.Logging = true
mail.silent = true
mail.From = eFromEmail
mail.FromName = eFromName
mail.Subject = eSubject
mail.AddRecipient eToEmail
mail.Body = eBody

on error resume next
mail.send(gsMailHost)

elseif gsMailComponent = "ServerObjectsASPMail" then
'this is just the framework, it needs to be setup for attachment, cc, bcc, etc

set mail = Server.CreateObject("SMTPsvg.mail")
mail.RemoteHost = gsMailHost
mail.FromName = eFromName
mail.FromAddress = eFromEmail
mail.AddRecipient eToEmail, eToName
mail.Subject = eSubject
mail.BodyText = eBody

on error resume next
mail.SendMail

elseif gsMailComponent = "MYASPMAILComponent" then ' some other component
'then do something else

end if

End Sub%>


hope someone can point some issues...

Thanks in advance!

[jnroche]

still got that problem above.

[jnroche]

all problem solved. But if you have a way better freeware version of a mailing list that i can look into that would be awesome.

just for anyone out there who experience the same problem, the code below fixed it:

if gsMailComponent = "CDONTS" then

Set Mailer = Server.CreateObject("CDO.Message")
Set iConf = CreateObject("CDO.Configuration")
Set Flds = iConf.Fields
Flds("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
Flds.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "localhost"
Flds.Update
Set Mailer.Configuration = iConf
Mailer.To = eToEmail
Mailer.From = eFromEmail
Mailer.Subject = eSubject
Mailer.HTMLBody = eBody
if eAttachedFile <> "" then
Mailer.AttachFile = eAttachedFile
end if
if eCCEmail <> "" then
Mailer.Cc = eCCEmail
end if
if eBCCEmail <> "" then
Mailer.Bcc = eBCCEmail
end if
if eBoolHTML then
'Mailer.BodyFormat = 0
'Mailer.MailFormat = 0
end if
Mailer.Send
Set Mailer = Nothing